home *** CD-ROM | disk | FTP | other *** search
/ Programmer Power Tools / Programmer Power Tools.iso / pcmag / vol7n17.arc / DO.BAT < prev    next >
Encoding:
DOS Batch File  |  1988-09-06  |  1.3 KB  |  48 lines
  1. @ECHO OFF
  2. IF %1X==X GOTO NOPAR
  3. GOTO _%1
  4. REM ---------------------- Lists available functions
  5. :_LIST
  6.    ECHO VALID COMMANDS ARE:
  7.    TYPE %0.BAT | FIND ":_" | FIND/V "FIND/V" | MORE
  8.    GOTO END
  9. REM ---------------------- Finds files anywhere on disk
  10. :_WHERE string [d:]
  11.    CHKDSK %3 /V | FIND "%2"
  12.    GOTO END
  13. REM ---------------------- DIR of directories only
  14. :_DDIR [path]
  15.    DIR %2 | FIND "<DIR>"
  16.    GOTO END
  17. REM ---------------------- DIR of files only
  18. :_FDIR [path]
  19.    DIR %2 | FIND/V "<DIR>" | FIND/V "  0  " | FIND/V "free"
  20.    GOTO END
  21. REM ---------------------- Adds path to current PATH environment
  22. :_ADDPATH path
  23.    PATH=%PATH%;%2
  24.    PATH
  25.    GOTO END
  26. REM ---------------------- Sets or returns to home directory
  27. :_HOME [path]
  28.    IF %2X==X GOTO CHANGE
  29.       SET HOMEDIR=%2
  30.       :CHANGE
  31.         IF NOT %HOMEDIR%X==X CD %HOMEDIR%
  32.    GOTO END
  33. REM ---------------------- TYPEs file one screen at a time
  34. :_SEE filename
  35.    TYPE %2 | MORE
  36.    GOTO END
  37. REM ---------------------- Copies to new path, deletes from old
  38. :_MOVE pathname pathname
  39.    COPY %2 %3
  40.    DEL %2
  41.    GOTO END
  42. REM ---------------------- No function error message
  43. :NOPAR
  44.    ECHO Error - No FUNCTION specified
  45.    ECHO         For list type " %0 LIST "
  46.    GOTO END
  47. :END
  48.